$C      g-tabAIV.tex  !
   GLIM 4 Program to Obtain Table AIV (same as Table A1 in Paper)  !
   If you are using the UNIX version of GLIM 4 you run glim:       !
   ef%    glim log=log-tabAIV.txt                                  !
    At the ? prompt in GLIM (include dollar sign before in)        !
    give the command " in 'g-tabAIV.txt'                           !
   The output will be in "g-tabaiv_log.tex"                        !
                                                                   !
$mac title     Oak Ridge Workers Mortality Study ORNL-6785         !
   Appendix Table AIV  Summary Results For White Males             !
  Ever Employed at X-10 Y-12  Lag= 10 years c1= ALL CANCER         !
$endmac $
$units  4230  $factors F 3 XG 10 IG 3 B 5 BG 5 S 2 L 2 !
$pr title $
!
$c Input  from g-tabaiv.tex  !
$tr $
$dinput 'gdata.txt' age F XG IG B S L y1 e1 Dmrem  PY  $

$ca  D = Dmrem/100  ! dose in mSv

$tab the py total for XG;F into py1 by X_;F_$
!
$tab the y1 total for XG;F into ob1 by X_;F_ !
$tab the e1 total for XG;F into ex1 by X_;F_ !
$tab the D mean with PY for XG;F  into DD using P_ by X_;F_ $
$tab the DD mean with P_ for X_ into d2$
$ca smr=100*ob1/ex1 !
$c           Estimated Deaths Adjusted using External Rates !
               and  Main Effects Model--  ageS +B+S+L+IG+F  !
$ca rb= y1/e1 :ageS= (age-52.5)/100 !
$err p $yvar rb  $we e1 !
$fit  ageS-1+B+S+L+IG+F  $di e $rec 9 !
$ca ae1= e1*%fv !
$tab the ae1 total for XG;F into aex1 by X_;F_ !
$acc 4 2 !
$tr i o $
$pr : 'Observed and Expected Deaths For Facility by Dose Group ' :
$tpr py1;ob1;ex1;aex1  X_;F_ $!
$pr '----------------------------------------'$

$pr : *margin 5 'Marginal Totals By Facility' :!
$pr '        Person Years ' $tab the py1 total for F_ $
$pr : '        Observed Deaths    ' $tab the ob1 total for F_ $
$pr : ' Expected Deaths (based on U.S. White Males) '!
         $tab the ex1 total for F_ $
$pr :'    Adjusted Expected ' $tab the aex1 total for F_ $
!
$tab the py1 total for X_ into py2 $
$tab the ob1 total for X_ into ob2 !
$tab the ex1 total for X_ into ex2 !
$tab the aex1 total for X_ into aex2 !
$ca sm2=100*ob2/ex2 !
$ca asm2=100*ob2/aex2 !
$as Grp= 1...10 $acc 4 1 $
$pr :: '              Marginal Totals For Dose Groups':: !
'  Group    Pyrs       Dose    Obs     Exp     SMR    AdjExp   AdjSMR' !
$look (s=-1) Grp  py2  d2 ob2 ex2 sm2  aex2 asm2 $

$RETURN