log log-tabav.txt @                 !  output to log file
!    af-tabav.txt
!  Oak Ridge Mortality Study:  X-10 Y-12 Evers
!   setup for amfit-- ERR Main Effects Model 
!   see epicure User's Guide and Command Summary
!   run amfit and at the prompt input this file, i.e. 
! < af-tabav.txt
!
!    see variables.txt ( same as Appendix Table AIII ORNL-6785 )
!         for definitions of variable
NAMES age F XG IG B S L y1 e1 D  PY @ !
INPUT gdata.txt   @                   ! read data from gdata.txt
TRAN LAGE= log(age/52.5) @            !  log age for power law model
TRAN  D = D/100000 @                  !  D= dose in Sv
TRAN C= py/1000 ; BRATE=e1/C;  LBR=log(BRATE) @
TRAN ageS= (age-52.5)/100 @
TRAN A = (age-12.5)/5 @               !  A is age expressed as a factor

LEVELS F 3 XG 10 IG 3 B 5  S 2 L 2 A 15  @

! SELECT XG < 10 @  ! remove first ! to select low dose data

CASES y1 @   !  observed events
pyr C    @   !  person-years ( 1000s )
!______________________________________________________________
!                  Fit Main Effects Model
!        Internal Baseline Based on Power Law For Age
!           With Linear Excess Relative Risk (ERR)
!_____________________________________________________________
NOSTRATA @
FITOPT S nointercept  @
LOGLINEAR 0 LAGE B S L IG  F  @  !  baseline rates
!
LINEAR 1 D=0 @ FIT @
NULL  @         ! Rererence model for likelihood ratio test
LINEAR 1 +D @
SCORE  @        !  Score test for Excess Relative Risk
                ! ERR cannot be less than -1/4.617 ( max dose)
LINEAR 1 D @ PARA 17 <20 > -0.216 @
FIT @LRT @      !  Likelihood ratio test
BOUND 17 @      !  95% likelihood-based  CI for ERR
!______________________________________________________________
!                        Fit Main Effects Model
!     Use External Rates--  see epicure user's guide Chapter 7
!        Below use LBR =  LOG(BRATE) as "offset"
!           With Linear Excess Relative Risk (ERR)
!_____________________________________________________________
LOGLINEAR 0 LBR=1  ageS B S L IG  F  @  !  baseline rates
LINEAR 1 D=0 @ FIT @
NULL  @         ! Rererence model for likelihood ratio test
LINEAR 1 +D @
SCORE  @        !  Score test for Excess Relative Risk
LINEAR 1 D @ PARA 18 <20 > -0.216 @
FIT @LRT @      !  Likelihood ratio test
BOUND 18 @      !  95% likelihood-based  CI for ERR
END @